Мир фракталов

Матрица статей Список статей Всячина Контакты

Звёздные фракталы

Звёздный фрактал состоит из правильной пятиконечной звезды с гирляндой из пяти меньших образцов. Каждая из этих пяти более мелких звёзд несёт на своих четырёх свободных концах ещё более мелкие звёзды. Этот процесс можно продолжать бесконечно, и в результате мы получим звёздный фрактал изображённый на рисунке. Этот фрактал строится как замкнутая ломаная линия, каждый следующий отрезок которой отклоняется всега на один и тот же угол $\alpha$ . Фрагмент с $\alpha = \frac{4\pi}{5}$ изображён на рисунке ниже.

Рассмотрим предфрактал пятого порядка. Предположим, что отрезки пронумерованы от 0 до $1279$ . Если первый отрезок с индексом $n = 0$ имеет направление $\varphi = 0$ , то направление произвольного отрезка с индексом $n$ будет $\alpha n$ . При построении такого фрактала мы должны иметь правило, по которому определяется длина $n$ -ого отрезка, если мы знаем длину $(n - 1)$ -го отрезка. Для случая, изображённого на рисунке, имеем 5 различных длин: $1$ , $r$ , $r^2$ , $r^3$ , $r^4$ , где $r$ — показатель уменьшения.

Правило, на котором основано построение, следующее:

$\begin{array}{l|l} n = 1, 2, 3, 5, 6, 7, 9, 10, 11, 13, \ldots & r^4, \\ n = 4, 8, 12, 20, 24, 28, 36, 40, 44, 52, \ldots & r^3, \\ n = 16, 32, 48, 80, 96, 112, \ldots & r^2, \\ n = 64, 128, 192, 320, 384, 448, \ldots & r^1, \\ n = 0, 256, 512, 768, 1024, \ldots & 1. \end{array}$

Отсюда следует, что длина отрезка с индексом n зависит от числа множителей $4$ в $n$ . Приведём программу реализующую данный алгоритм:

program Star;

uses Crt, Graph;

const
	it = 1280;
	r = 0.35;
	l = 300;
	da = 4 * pi/5;
	v = 4;

var
	gd, gm : Integer;
	a      : Real;
	x, y   : Real;
	xn, yn : Real;
	i      : Integer;

function Mn(nn: Integer): Real;

begin
	if nn mod (v*v*v*v) = 0 then 
		Mn := 1     
	else if nn mod (v*v*v) = 0 then 
		Mn := r     
	else if nn mod (v*v) = 0 then 
		Mn := r * r   
	else if nn mod v = 0 then 
		Mn := r * r * r 
	else
                Mn := r * r * r * r;
end;

begin
	gd := Detect;
	InitGraph(gd,gm,'c:\bp\bgi');
	a := 0;
	x := 200;
	y := 320;
	for i := 0 to it do 
	begin
		xn := x + sin(a)*l*Mn(i);
		yn := y - cos(a)*l*Mn(i);
		Line(Round(x), Round(y), Round(xn), Round(yn));
		x := xn;
		y := yn;
		a := a + da;
	end;
	ReadKey;
	CloseGraph;
end.

Теперь обобщим это правило на другие звёздные фракталы. Обозначим порядок предфрактала символом $p$ и возмём произвольное число $\nu$ вместо 4. Тогда мы получим следующее правило:

$\begin{array}{l|l} \nu \,\not|\, n & r^{p-1}, \\ \nu \,|\, n, \quad \nu^2 \,\not|\, n \quad & r^3, \\ \ldots & \ldots \\ \nu^{p-1} \,|\, n & 1. \end{array}$

Ссылки:

Star Fractal ,
А. Д. Морозов Введение в теорию фракталов. — Москва-Ижевск: Институт компьютерных исследований, 2002. 50—53.