Мир фракталов

Матрица статей Список статей Всячина Контакты

Фрактал Ньютона

Области с фрактальными границами появляются при приближенном нахождении корней нелинейного уравнения $f(z) = 0$ алгоритмом Ньютона на комплексной плоскости. Для функции действительной переменной метод Ньютона часто называют методом касательных. Поясним суть этого метода.

Пусть нам задана функция $f(x)$ , для которой известно приближенное значение ее корня $x_1$ , а также значение функции в этой точке $f(x_1)$ и значение её первой производной $f'(x_1)$ . Тогда, проводя касательную к графику функции $f(x)$ в этой точке и определяя ее пересечение с осью $Ox$ , мы получим уточненное положение корня $x_2$ .

Т. к. уравнение касательной к $f(x)$ в точке $x_1$ выглядит следующим образом:

$y = f'(x_1)(x - x_1) + f(x_1),$ то, приравнивая $y$ нулю, получаем, что уточненное значение корня $x_2$ связано с предыдущим значением $x_1$ соотношением $x_2 = x_1 - \frac{f(x_1)}{f'(x_1)}.$ Беря теперь значение $x$ в качестве приближенного и повторяя эту процедуру, находим следующее приближение корня $x_3$ и т. д. При некоторых условиях эта последовательность сходится к корню уравнения $f(x) = 0$ .

Рассмотрим теперь комплексный случай. Рассмотрим уравнение $f(z) = 0$ и последовательность

$z_{n + 1} = z_n - \frac{f(z_n)}{f'(z_n)}.$

Пусть $f(z) = z^3 - 1$ . Как известно, это уравнение имеет три корня $w_1$ , $w_2$ , $w_3$ . При выборе различных $z_0$ процесс будет сходится к различным корням. Обозначим эти области притяжения через $A(w_i) = \{z_0 \,|\, z_n \to w_i\}$ . Артур Кэли поставил задачу описания областей $A(w_i)$ . Оказывается границы этих областей имеют фрактальную структуру.

program N3;
uses Graph, Crt;
type
	Complex = Record
		x : Real;
		y : Real;
	end;
const
	iter = 50;
	max  = 1e+6;
	min  = 1e-6;
	
var
	z, t, d : Complex;
	p       :  Real;
	x, y, n : Integer;
	Cancel  : Boolean;
	gd, gm  : Integer;
	mx, my  : Integer;
	
begin
	Cancel := False;
	Randomize;
	gd := Detect;
	InitGraph(gd,gm,'c:\bp\bgi');
	Mx := GetMaxX div 2;
	My := GetMaxY div 2;
	for y := -my to my do
		for x := -mx to mx do 
		begin
			n := 0;
			z.x := X * 0.005;
			z.y := Y * 0.005;
			d := z;
			while (sqr(z.x)+sqr(z.y) < max) and (sqr(d.x)+sqr(d.y) > min)
				and (n < iter) do 
			begin
				t := z;
				{z^3 - 1}
				p := sqr(sqr(t.x)+sqr(t.y));
				z.x := 2/3*t.x + (sqr(t.x)-sqr(t.y))/(3*p);
				z.y := 2/3*t.y*(1-t.x/p);{}
				d.x := abs(t.x - z.x);
				d.y := abs(t.y - z.y);
				Inc(n);
				if keypressed then 
					Cancel := true;
			end;
			PutPixel(mx + x,my + y,16 - (n mod 16));
			if cancel then exit;
		end;
	Readkey;
	CloseGraph;
end.

Смотрите также:

множества Мандельброта и Жюлиа.

Ссылки:

Морозов А. Д. Введение в теорию фракталов. — Москва-Ижевск: Институт компьютерных исследований, 2002, 109—111.
Р. М. Кроновер. Фракталы и хаос в динамических системах. Основы теории. Москва: Постмаркет, 2000. 248—251.
Метод Ньютона .
Newton fractal .
Newton's Method .
Gallery of fractals created using the Newton Raphson method .