Мир фракталов

Матрица статей Список статей Всячина Контакты

Фракталы и системы счисления

Некоторые фрактальные кривые можно строить следующим образом. Пусть необходимо постоить предфрактал порядка $p$ . Он представляет собой совокупность отрезков. Пронумеруем их от 0 до $N$ . Тогда направление отрезка с номером $n$ определяется функцией $\Phi(n)$ , которая имеет вид

$\Phi(n) = \sum_{i}a(n_i),$ где $n_i$ — $i$ -й разряд числа $n$ в системе счисления по основанию $m$ , $a{:}\,0..m-1 \to [0, 2\pi]$ .

Рассмотрим кривую Коха. Воспользуемся системой счисления по основанию 4. Определим функцию $a(t)$ следующим образом:

$a(t) = \left\{ \begin{array}{rr} 0, & t = 0, \\ \frac{\pi}{3}, & t = 1, \\ -\frac{\pi}{3}, & t = 2, \\ 0, & t = 3. \end{array} \right.$

Ниже приведена программа построения кривой Коха с использованием данного алгоритма.

program Koch;

uses CRT, Graph;

const
	p = 4;
	
var
	gd, gm: Integer;
	i: Integer;
	x, y, l: Real;
	a: Real;
	n, m, k: Integer;
	
begin
	gd := Detect;
	InitGraph(gd, gm, 'c:\bp\bgi');
	x := 0;
	y := 400;
	l := 640 / (exp(p*ln(3)));
	MoveTo(Round(x), Round(y));
	for i := 0 to Round(exp(p*ln(4)))-1 do 
	begin
		a := 0;
		n := i;
		k := 0;
		repeat
			m := n mod 4;
			n:=n div 4;
			case m of
				0: a := a + 0;
				1: a := a - pi/3;
				2: a := a + pi/3;
				3: a := a + 0;
			end;
			inc(k);
		until k >= p;
		x := x + l*cos(a);
		y := y + l*sin(a);
		LineTo(Round(x), Round(y));
	end;
	ReadKey;
	CloseGraph;
end.

Рассмотрим построение обобщения кривой Коха с восьмизвенным генератором. Для этого воспользуемся восьмеричной системой счисления и функцию $a(t)$ определим следующим образом:

$a(t) = \left\{ \begin{array}{rr} 0, & t = 0, \\ -\frac{\pi}{2}, & t = 1, \\ 0, & t = 2, \\ \frac{\pi}{2}, & t = 3, \\ \frac{\pi}{2}, & t = 4, \\ 0, & t = 5. \\ -\frac{\pi}{2}, & t = 6, \\ 0, & t = 7. \end{array} \right.$

program Koch10;

uses CRT, Graph;

const
	p = 4;
	
var
	gd, gm: Integer;
	i: Integer;
	x, y, l: Real;
	a: Real;
	n, m, k: Integer;
	
begin
	gd := Detect;
	InitGraph(gd, gm, 'c:\bp\bgi');
	x := 0;
	y := 240;
	l := 640 / (exp(p*ln(4)));
	MoveTo(Round(x), Round(y));
	for i := 0 to Round(exp(p*ln(8)))-1 do 
	begin
		a := 0;
		n := i;
		k := 0;
		repeat
			m := n mod 8;
			n := n div 8;
			case m of
				0: a := a + 0;
				1: a := a - pi/2;
				2: a := a + 0;
				3: a := a + pi/2;
				4: a := a + pi/2;
				5: a := a + 0;
				6: a := a - pi/2;
				7: a := a + 0;
			end;
			inc(k);
		until k >= p;
		x := x + l*cos(a);
		y := y + l*sin(a);
		LineTo(Round(x), Round(y));
	end;
	ReadKey;
	CloseGraph;
end.

Для построения кривой Леви воспользуется двоичной системой счисления,

$a(t) = \left\{ \begin{array}{ll} \frac{\pi}{4}, & t = 0, \\ -\frac{\pi}{4}, & t = 1. \end{array} \right.$ Но если определить функцию $a(t)$ следующим образом: $a(t) = \left\{ \begin{array}{ll} 0, & t = 0, \\ \frac{\pi}{2}, & t = 1, \end{array} \right.$ то не сложно заметить, что $\Phi(n) = \frac{S(n)\pi}{2}$ , где $S(n)$ — сумма всех разрядов в представлении числа $n$ в двоичной системе.

program Levy;

uses CRT, Graph;

const
	p = 12;
  
var
	gd, gm: Integer;
	i: Integer;
	x, y, l: Real;
	a: Real;
	n, m, k: Integer;
	
begin
	gd := Detect;
	InitGraph(gd, gm, 'c:\bp\bgi');
	x := 300;
	y := 240;
	l := 3;
	MoveTo(Round(x), Round(y));
	for i := 0 to Round(exp(p*ln(2)))-1 do 
	begin
		a := 0;
		n := i;
		m := 0;
		k := 0;
		repeat
			m := n mod 2;
			n := n div 2;
			case m of
				0: a := a+pi/4;
				1: a := a-pi/4
			end;
			inc(k);
		until k >= p;
		x := x + l*cos(a);
		y := y + l*sin(a);
		LineTo(Round(x), Round(y));
	end;
	ReadKey;
	CloseGraph;
end.

Смотрите также:

Ссылки:

Морозов А. Д. Введение в теорию фракталов. — Москва-Ижевск: Институт компьютерных исследований, 2002, 25—37.
Газале М. ГНОМОН. От фараонов до фракталов. Москва-Ижевск: Институт компьютерных исследований, 2002, 245—253.